plugins {
    id "com.github.node-gradle.node" version "5.0.0"
    id "run.halo.plugin.devtools" version "0.0.9"
    id "io.freefair.lombok" version "8.0.1"
    id 'java'
}

group 'run.halo.links'
sourceCompatibility = JavaVersion.VERSION_17

repositories {
    maven { url 'https://s01.oss.sonatype.org/content/repositories/snapshots' }
    maven { url 'https://repo.spring.io/milestone' }
    mavenCentral()
}

dependencies {
    implementation platform('run.halo.tools.platform:plugin:2.15.0-SNAPSHOT')
    compileOnly 'run.halo.app:api'

    testImplementation 'run.halo.app:api'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

test {
    useJUnitPlatform()
}

node {
    pnpmVersion = '8'
    nodeProjectDir = file("${project.projectDir}/console")
}

tasks.register("installDeps", PnpmTask) {
    onlyIf { !file("${project.projectDir}/console/node_modules").exists() }
    args = ['install']
}

tasks.register("buildFrontend", PnpmTask) {
    args = ['build']
    dependsOn("installDeps")
}

tasks.named("compileJava").configure {
    dependsOn("buildFrontend")
}

halo {
    version = '2.15'
}