@echo off

setlocal

REM 设置日志的目录
set "copy_log_file=Archive_log.log"

REM 设置源文件夹和目标文件夹的路径
set "source_folder=C:\ProgramData\PopCap Games\PlantsVsZombies\pvzHE\yourdata"
set "destination_folder=%cd%\我的存档\faintdream"

echo -------------------->> "%copy_log_file%" 2>&1
echo [%computername%][%date% %time%][备份存档]>> "%copy_log_file%" 2>&1

REM 检查源文件夹是否存在
if not exist "%source_folder%" (
    echo 存档源文件夹[%source_folder%]不存在。 >> "%copy_log_file%" 2>&1
    msg * 没有找到存档。
    exit /b
)

:: REM 检查目标文件夹是否存在，如果不存在则创建
:: if not exist "%destination_folder%" (
::     echo 目标文件夹不存在，尝试创建文件目标。 >> "%copy_log_file%" 2>&1
::     mkdir "%destination_folder%" || (
::         msg * 目标文件夹创建失败，请检查权限设置。
::         echo 目标文件夹创建失败，请检查权限设置。 >> "%copy_log_file%" 2>&1
::         exit /b
::     )
:: )

REM 使用 xcopy 命令进行文件夹复制
REM /E 参数会复制包括子文件夹在内的所有目录和文件
REM /C 参数表示允许复制过程中遇到错误时继续进行
REM /I 参数表示如果目标是目录且不存在，则认为它是一个目录
REM /Q 参数表示不显示文件复制过程
REM /H 参数表示复制隐藏文件和系统文件
REM /Y 参数表示直接覆盖同名文件，无需确认
xcopy "%source_folder%" "%destination_folder%" /E /C /I /Q /Y /H >> "%copy_log_file%" 2>&1

REM 执行到这里证明复制成功(其实这段代码不具有判定功能)
if exist "%destination_folder%\*" (
    :: msg * 备份存档成功，已经将存档%source_folder% 备份到 %destination_folder%
    echo 备份存档成功，已经将存档%source_folder% 备份到 %destination_folder% >> "%copy_log_file%" 2>&1
) else (
    msg * 备份存档失败，请查看日志
    echo 备份存档失败 >> "%copy_log_file%" 2>&1
    exit /b
)

REM 运行另一个脚本,提交推送
call git-push.bat

msg * 备份存档成功备份到 %destination_folder%

endlocal