;一个有界面的简单闹钟程序。脚本也有值得参考的地方

SetTimer,Alert,1000		;总体Timer，每秒检查一次条件是否成立。比sleep好得多，sleep会导致各种反应不灵。每一次调用标签代码都是独立的，直接相当于多线程呀

clockOn=-1	;是否已经开启闹钟
 
Gui, Add, Text,, 小时:
Gui, Add, Text,, 分钟:
Gui, Add, Text,, 消息:
Gui, Add, Edit, vHour ym Number Limit2 w60 ,% A_Hour 	; 一堆控件设定在控件类型后面的参数，每个设定是一个字符串用空格分开.The ym option starts a new column of controls.
Gui, Add, Edit, vMinute Number Limit2 w60,% A_Min	;设定的时、分保存在Hour和Minute变量中
Gui, Add, Edit, vMsg w60,ysy时间到!		;时间到时显示的消息

Gui, Add, Button, default ym, 计时 ; 如果标签 Button计时 存在，则当用户点击按钮时会自动调用该标签。
Gui, Add, Button,, 退出 ;去ButtonExit标签
Gui, Add, Button,, 状态	;显示设置状况

Gui, Show,w200h100,闹钟

return ; 自动运行片段结束。脚本保持空闲直到用户对窗口操作。

Button计时:

Gui, Submit,NoHide	; 保存用户输入后每个控件的数据

if ((Hour<0) or (Minute<0) or (Hour>23) or (Minute>59)){
	MsgBox,输入时间不正确
	return
}

MsgBox,将在%Hour%时%Minute%分后出现提示.现在是%A_Hour%时%A_Min%分.
clockOn=1	;对话框结束后才开始也重要，否则可能在该对话框结束前就开始计时弹出提醒框了

return	;用来结束标签,文件后面标签多的时候就要这样

Alert:

if (clockOn>0){

		if ((A_Hour=Hour) && (A_Min=Minute)){
			clockOn=-1	;先把闹钟关掉，否则会等到对话框结束后才关，可能没有关掉就迎来下一个计时代码，会连续出现对话框
			MsgBox,%Msg%
		}
	}

return 

GuiClose:
Button退出:
ExitApp
return

Button状态:

if (clockOn>0){
	MsgBox,将在%Hour%时%Minute%分后出现提示.现在是%A_Hour%时%A_Min%分.
}else{
	MsgBox,现在是%A_Hour%时%A_Min%分.闹钟尚未开启
}

return