configurations {
    mybatisGenerator
}


dependencies {
    mybatisGenerator 'org.mybatis.generator:mybatis-generator-core:1.3.2'
    mybatisGenerator 'mysql:mysql-connector-java:5.1.30'
    mybatisGenerator 'tk.mybatis:mapper:3.3.8'
    mybatisGenerator 'com.ch:ch-mybatis-generator:1.0.2-SNAPSHOT'
}

def dbProperties = {
    def properties = new Properties()
    // src/main/resources/
    file("generatorConfig.properties").withInputStream { inputStream ->
        properties.load(inputStream)
    }
    properties
}

task mybatisGenerate {
    group 'mybatis'
    doLast {
        def properties = dbProperties()

        ant.properties['targetProject'] = projectDir.path
        ant.properties['driverClass'] = properties.getProperty("jdbc.driverClassName")
        ant.properties['connectionURL'] = properties.getProperty("jdbc.url")
        ant.properties['userId'] = properties.getProperty("jdbc.username")
        ant.properties['password'] = properties.getProperty("jdbc.password")
        ant.properties['package'] = properties.getProperty("my.package")
        ant.properties['table'] = properties.getProperty("my.table")
        ant.properties['modelName'] = properties.getProperty("my.pojo.name")
        ant.properties['src_main_java'] = sourceSets.main.java.srcDirs[0].path
        ant.properties['src_main_resources'] = sourceSets.main.resources.srcDirs[0].path

        ant.taskdef(
                name: 'mbgenerator',
                classname: 'org.mybatis.generator.ant.GeneratorAntTask',
                classpath: configurations.mybatisGenerator.asPath
        )
        ant.mbgenerator(overwrite: true,
//                configfile: "$parent.projectDir/" + properties.getProperty("config.file.name"), verbose: true) {
                configfile: "$projectDir/" + properties.getProperty("config.file.name"), verbose: true) {
            propertyset {
                propertyref(name: 'targetProject')
                propertyref(name: 'userId')
                propertyref(name: 'driverClass')
                propertyref(name: 'connectionURL')
                propertyref(name: 'password')
                propertyref(name: 'package')
                propertyref(name: 'table')
                propertyref(name: 'modelName')
                propertyref(name: 'src_main_java')
                propertyref(name: 'src_main_resources')

            }
        }
    }
}