*-3.3    暂  元
*---------------------

      *   ==本节目录==
      
      *   3.3.1 暂元的定义和引用
      *         3.3.1.1 赞元的基本功能
      *         3.3.1.2 暂元中的暂元
      *   3.3.2 全局暂元


*-------------------------
*-3.3.1 暂元的定义和引用

  *-3.3.1.1 暂元的基本功能
  
    help local
  
    *-存放数字
      local a = 5
      dis `a'
      local b = `a' + 7
      dis `b'
  
    *-存放文字
  
    *-存放变量名称
      sysuse auto, clear
	  local v1 "price"
      local v2 "weight rep78 length"
      sum `v1' `v2'
      des `v1' `v2'
	  reg `v1' `v2'
	  
	*-长字符的存放 
      sysuse auto, clear
	  local v1 "price"
      local v1 "`v1' weight rep78 length"
      sum `v1'
      des `v1' 
	  reg `v1' 	  

  
  *-3.3.1.2  暂元中的暂元
   
     local a1 = 2
     local a2 "var"
     local a3 = 2*`a1'
     local a4 `a`a1''  // 从第一个完整的 ` ' 开始分析 
     local `a2'`a1' = 2*`a3'
     
     dis  `a1'
     dis "`a2'"  
     dis  `a3'          // 4 
     dis "`a4'"         // 暂元 a2 中的内容 
     dis ``a2'`a1''     // 8 

	 
  *-暂元的高级功能
  
    help macro
    help extended_fcn
	help macrolists    //各类处理文字的暂元功能
	help tokenize      //暂元的分解和切割
	help gettoken


*----------------------
*-3.3.2  全局暂元

  *- 定义和引用方式
     global aa "This is my first program!"      
     dis "$aa"
	 macro dir   //列示内存中已经定义的暂元

     global x1 = 5
     global x2 = 2^$x1
     dis $x2
   
  *- 示例： 
  
     sysuse nlsw88, clear
     local  robust ",robust"    //公共选项
     global test "age married hours ttl_exp" //控制变量
	 
	 reg wage $test `control' `robust' 
     est store m0
	 
	 local control "i.race"
     reg wage $test `control' `robust' 
     est store m1
   
	 local control "i.industry"
     reg wage $test `control' `robust' 
     est store m2
	 
	 local control "i.occupation"
     reg wage $test `control' `robust' 
     est store m3	 
   
     esttab m0 m1 m2 m3, nogap s(N r2_a) addnote("`robust'")